SysMets2.mod: Translation to Stony Brook Modula-2

Last updated: 17. 1.1998, 18:56

<*/NOWARN:F*>
(*----------------------------------------------------
   SYSMETS2.C      --- System Metrics Display Program No. 2
                   (c) Charles Petzold, 1996
   SysMets2.mod    --- Translation to Stony Brook Modula-2
                   (c) Peter Stadler,   1997
  ----------------------------------------------------*)


MODULE SysMets2;
IMPORT SYSTEM;
IMPORT WINUSER;
IMPORT WIN32;
IMPORT WINGDI;
IMPORT SysMets;
IMPORT Strings;
IMPORT WINX;
CONST
  szAppName = "SysMets2";
VAR
  hwnd        :  WIN32.HWND;
  msg         :  WINUSER.MSG;
  wc          :  WINUSER.WNDCLASSEX;
  cxChar, cxCaps, cyChar, cyClient,
  iVscrollPos : INTEGER;
(*++++*****************************************************************)
PROCEDURE MaxInt (a,b : INTEGER) : INTEGER;
(**********************************************************************)
BEGIN
  IF(a>b) THEN
    RETURN a;
  ELSE
    RETURN b;
  END;
END MaxInt;
(*++++*****************************************************************)
PROCEDURE MinInt (a,b : INTEGER) : INTEGER;
(**********************************************************************)
BEGIN
  IF(a>b) THEN
    RETURN b;
  ELSE
    RETURN a;
  END;
END MinInt;
<*/PUSH*>
%IF WIN32 %THEN
    <*/CALLS:WIN32SYSTEM*>
%ELSE
    <*/CALLS:WINSYSTEM*>
%END
(*++++*****************************************************************)
PROCEDURE  WndProc (hwnd        : WIN32.HWND;
                    iMsg        : WIN32.UINT;
                    wParam      : WIN32.WPARAM;
                    lParam      : WIN32.LPARAM) : WIN32.LRESULT [EXPORT];
(**********************************************************************)
VAR
  szBuffer    :  ARRAY[0..10] OF CHAR;
  hdc         :  WIN32.HDC;
  i, y        :  INTEGER;
  ps          :  WINUSER.PAINTSTRUCT;
  tm          :  WINGDI.TEXTMETRIC;
BEGIN

  CASE (iMsg) OF
          | WINUSER.WM_CREATE :
               hdc := WINUSER.GetDC (hwnd);

               WINGDI.GetTextMetrics (hdc, tm);
               cxChar := tm.tmAveCharWidth;
               IF(tm.tmPitchAndFamily=1) THEN
                 cxCaps := 3*cxChar/2;
               ELSE
                 cxCaps := 2*cxChar/2;
               END;
               cyChar := tm.tmHeight + tm.tmExternalLeading;

               WINUSER.ReleaseDC (hwnd, hdc);

               WINUSER.SetScrollRange (hwnd, WINUSER.SB_VERT, 0, SysMets.NUMLINES, FALSE);
               WINUSER.SetScrollPos   (hwnd, WINUSER.SB_VERT, iVscrollPos, TRUE);
               RETURN 0;

          | WINUSER.WM_SIZE :
               cyClient := WINUSER.HIWORD (lParam);
               RETURN 0;

          | WINUSER.WM_VSCROLL :
               CASE (WINUSER.LOWORD (wParam)) OF
                    | WINUSER.SB_LINEUP :
                         iVscrollPos := iVscrollPos - 1;

                    | WINUSER.SB_LINEDOWN :
                         iVscrollPos := iVscrollPos + 1;

                    | WINUSER.SB_PAGEUP :
                         iVscrollPos :=iVscrollPos-cyClient DIV cyChar;

                    | WINUSER.SB_PAGEDOWN :
                         iVscrollPos :=iVscrollPos+ cyClient DIV cyChar;

                    | WINUSER.SB_THUMBPOSITION :
                         iVscrollPos := WINUSER.HIWORD (wParam);

                    ELSE
                    END;
               iVscrollPos := MaxInt (0, MinInt(iVscrollPos, SysMets.NUMLINES));

               IF (iVscrollPos # WINUSER.GetScrollPos (hwnd, WINUSER.SB_VERT)) THEN
                    WINUSER.SetScrollPos (hwnd, WINUSER.SB_VERT, iVscrollPos, TRUE);
                    WINUSER.InvalidateRect (hwnd, WINX.NIL_RECT, TRUE);
               END;
               RETURN 0;

          | WINUSER.WM_PAINT :
               hdc := WINUSER.BeginPaint (hwnd, ps);

               FOR i := 0 TO  SysMets.NUMLINES-1 DO
                    y := cyChar * (1 - iVscrollPos + i);

                    WINGDI.TextOut (hdc, cxChar, y,
                             SysMets.sysmetrics[i].szLabel,
                             LENGTH(SysMets.sysmetrics[i].szLabel));

                    WINGDI.TextOut (hdc, cxChar + 22 * cxCaps, y,
                             SysMets.sysmetrics[i].szDesc,
                             LENGTH(SysMets.sysmetrics[i].szDesc));

                    WINGDI.SetTextAlign (hdc, WINGDI.TA_RIGHT BOR WINGDI.TA_TOP);

                    WINGDI.TextOut (hdc, cxChar + 22 * cxCaps + 40 * cxChar, y,
                             szBuffer,
                             WINUSER.wsprintf (szBuffer, "%5d",
                                         WINUSER.GetSystemMetrics (SysMets.sysmetrics[i].iIndex)));                
					 
                    WINGDI.SetTextAlign (hdc, WINGDI.TA_LEFT BOR WINGDI.TA_TOP);
               END;

               WINUSER.EndPaint (hwnd, ps);
               RETURN 0;

          | WINUSER.WM_DESTROY :
               WINUSER.PostQuitMessage (0);
               RETURN 0;
  ELSE

          RETURN WINUSER.DefWindowProc (hwnd, iMsg, wParam, lParam);
  END;
END WndProc;
<*/POP*>
(*++++*****************************************************************)
PROCEDURE InitApplication () : BOOLEAN;
(**********************************************************************)
VAR
  rc  :  INTEGER;
BEGIN
  wc.cbSize        := SIZE(WINUSER.WNDCLASSEX);
  wc.style         := WINUSER.CS_HREDRAW BOR WINUSER.CS_VREDRAW;
  wc.lpfnWndProc   := WndProc;
  wc.cbClsExtra    := 0;
  wc.cbWndExtra    := 0;
  wc.hInstance     := WINX.Instance;
  wc.hIcon         := WINUSER.LoadIcon (NIL, WINUSER.IDI_APPLICATION^);
  wc.hCursor       := WINUSER.LoadCursor (NIL, WINUSER.IDC_ARROW^);
  wc.hbrBackground := SYSTEM.CAST(WIN32.HBRUSH, WINGDI.GetStockObject (WINGDI.WHITE_BRUSH));
  wc.lpszMenuName  := NIL;
  wc.lpszClassName := SYSTEM.ADR(szAppName);
  wc.hIconSm       := WINUSER.LoadIcon (NIL, WINUSER.IDI_APPLICATION^);

  rc := WINUSER.RegisterClassEx (wc);
  RETURN rc#0;
END InitApplication;
(*++++*****************************************************************)
PROCEDURE InitMainWindow () : BOOLEAN;
(**********************************************************************)
BEGIN
  hwnd := WINUSER.CreateWindow
           (szAppName,                           (* window class name            *)
           "Get System Metrics No. 2: Translation to Stony Brook Modula-2",
                                                 (* window caption               *)
           WINUSER.WS_OVERLAPPEDWINDOW BOR WINUSER.WS_VSCROLL, (* window style           *)
           WINUSER.CW_USEDEFAULT,                (* initial x position           *)
           WINUSER.CW_USEDEFAULT,                (* initial y position           *)
           WINUSER.CW_USEDEFAULT,                (* initial x size               *)
           WINUSER.CW_USEDEFAULT,                (* initial y size               *)
           NIL,                                  (* parent window handle         *)
           NIL,                                  (* window menu handle           *)
           WINX.Instance,                        (* program instance handle      *)
           NIL);                                 (* creation parameters          *)

  IF hwnd = NIL THEN
    RETURN FALSE;
  END;
  WINUSER.ShowWindow (hwnd, WINUSER.SW_SHOWDEFAULT);
  WINUSER.UpdateWindow (hwnd);
  RETURN TRUE;
END InitMainWindow;
(*++++*****************************************************************)
BEGIN
  IF InitApplication()  AND  InitMainWindow() THEN
    WHILE (WINUSER.GetMessage(msg,NIL,0,0)) DO
      WINUSER.TranslateMessage(msg);
      WINUSER.DispatchMessage(msg);
    END;
  END;
END SysMets2.